From f8dbe8e0f771949f83e91b5e37a690e571a047ee Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?=EA=A6=8C=EA=A6=AB=EA=A6=B6=EA=A6=8F=EA=A7=80=EA=A6=A6?=
 =?UTF-8?q?=EA=A6=BF=EA=A6=A7=EA=A6=AE=EA=A6=91=EA=A6=A9=EA=A6=AD=EA=A7=80?=
 <erik@darapsa.co.id>
Date: Sun, 4 Jul 2021 15:29:04 +0800
Subject: Separated client code

---
 namatoko.pro | 50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 namatoko.pro

(limited to 'namatoko.pro')

diff --git a/namatoko.pro b/namatoko.pro
new file mode 100644
index 0000000..b2830b8
--- /dev/null
+++ b/namatoko.pro
@@ -0,0 +1,50 @@
+QT += quickcontrols2
+DEFINES += \
+	CA_BUNDLE=\\\"$$CA_BUNDLE\\\" \
+	SAMPLEURL=\\\"$$SAMPLEURL\\\" \
+	IMAGE_DIR=\\\"$$IMAGE_DIR\\\"
+debug: DEFINES += DEBUG
+HEADERS += controller.hxx
+SOURCES += \
+	main.cxx \
+	controller.cxx \
+	registration.c \
+	handler.c
+RESOURCES += \
+	namatoko.qrc \
+	qicpos.qrc \
+	larva.qrc \
+	larva/material-design-icons.qrc
+wasm {
+	QT += svg
+	QMAKE_CXXFLAGS += -std=c++11
+	LIBS += -ltidys
+}
+!wasm: LIBS += \
+	-ltidy \
+	-lcurl
+LIBS += \
+	-licclient
+!android: LIBS += -lqicclient
+android {
+	QT += svg
+	PREFIX = $$ANDROID_NDK_PATH/toolchains/llvm/prebuilt/$$ANDROID_NDK_HOST/sysroot/usr
+	TRIPLE = aarch64-linux-android
+	contains(ANDROID_TARGET_ARCH,armeabi-v7a): TRIPLE = arm-linux-androideabi
+	contains(ANDROID_TARGET_ARCH,x86): TRIPLE = i686-linux-android
+	contains(ANDROID_TARGET_ARCH,x86_64): TRIPLE = x86_64-linux-android
+	LIBS += \
+		-L$$PREFIX/lib/$$TRIPLE/$$API \
+		-L$$QT_ANDROID_LIBDIR \
+		-lqicclient_$$ANDROID_TARGET_ARCH
+	ANDROID_EXTRA_LIBS += \
+		$$PREFIX/lib/$$TRIPLE/$$API/libcrypto_1_1.so \
+		$$PREFIX/lib/$$TRIPLE/$$API/libssl_1_1.so \
+		$$PREFIX/lib/$$TRIPLE/$$API/libcurl.so \
+		$$PREFIX/lib/$$TRIPLE/$$API/libtidy.so \
+		$$PREFIX/lib/$$TRIPLE/$$API/libicclient.so \
+		$$QT_ANDROID_LIBDIR/libqicclient_$${ANDROID_TARGET_ARCH}.so
+	assets.path = /assets
+	assets.files = $$CA_BUNDLE
+	INSTALLS += assets
+}
-- 
cgit v1.2.3