QT += quickcontrols2
DEFINES += \
	CA_BUNDLE=\\\"$$CA_BUNDLE\\\" \
	SECURE_SERVER=\\\"$$SECURE_SERVER\\\"
debug: DEFINES += DEBUG
HEADERS += controller.hxx
SOURCES += \
	main.cxx \
	controller.cxx \
	registration.c \
	handler.c
RESOURCES += \
	namatoko.qrc \
	qicpos.qrc \
	larva.qrc \
	larva/material-design-icons.qrc
wasm {
	QT += svg
	QMAKE_CXXFLAGS += -std=c++11
	LIBS += -ltidys
}
!wasm: LIBS += \
	-ltidy \
	-lcurl
LIBS += \
	-licclient
!android: LIBS += -lqicclient
android {
	QT += svg
	PREFIX = $$ANDROID_NDK_PATH/toolchains/llvm/prebuilt/$$ANDROID_NDK_HOST/sysroot/usr
	TRIPLE = aarch64-linux-android
	contains(ANDROID_TARGET_ARCH,armeabi-v7a): TRIPLE = arm-linux-androideabi
	contains(ANDROID_TARGET_ARCH,x86): TRIPLE = i686-linux-android
	contains(ANDROID_TARGET_ARCH,x86_64): TRIPLE = x86_64-linux-android
	LIBS += \
		-L$$PREFIX/lib/$$TRIPLE/$$API \
		-L$$QT_ANDROID_LIBDIR \
		-lqicclient_$$ANDROID_TARGET_ARCH
	ANDROID_EXTRA_LIBS += \
		$$PREFIX/lib/$$TRIPLE/$$API/libcrypto_1_1.so \
		$$PREFIX/lib/$$TRIPLE/$$API/libssl_1_1.so \
		$$PREFIX/lib/$$TRIPLE/$$API/libcurl.so \
		$$PREFIX/lib/$$TRIPLE/$$API/libtidy.so \
		$$PREFIX/lib/$$TRIPLE/$$API/libicclient.so \
		$$QT_ANDROID_LIBDIR/libqicclient_$${ANDROID_TARGET_ARCH}.so
	assets.path = /assets
	assets.files = $$CA_BUNDLE
	INSTALLS += assets
}