blob: c8a509d8bf372d82a4fc1156a3b326a5d0282b80 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
QT += quickcontrols2
DEFINES += \
CA_BUNDLE=\\\"$$CA_BUNDLE\\\" \
SECURE_SERVER=\\\"$$SECURE_SERVER\\\"
debug: DEFINES += DEBUG
HEADERS += controller.hxx
SOURCES += \
main.cxx \
controller.cxx \
registration.c \
handler.c
RESOURCES += \
namatoko.qrc \
qicpos.qrc \
larva.qrc \
larva/material-design-icons.qrc
freebsd: LIBS += \
-lstdthreads
!wasm: LIBS += -lcurl
!wasm:!android: LIBS += -ltidy5
wasm {
QT += svg
QMAKE_CXXFLAGS += -std=c++11
LIBS += -ltidys
}
LIBS += \
-licclient
!android: LIBS += -lqicclient
android {
QT += svg
PREFIX = $$ANDROID_NDK_PATH/toolchains/llvm/prebuilt/$$ANDROID_NDK_HOST/sysroot/usr
TRIPLE = aarch64-linux-android
contains(ANDROID_TARGET_ARCH,armeabi-v7a): TRIPLE = arm-linux-androideabi
contains(ANDROID_TARGET_ARCH,x86): TRIPLE = i686-linux-android
contains(ANDROID_TARGET_ARCH,x86_64): TRIPLE = x86_64-linux-android
LIBS += \
-L$$PREFIX/lib/$$TRIPLE/$$API \
-L$$QT_ANDROID_LIBDIR \
-lqicclient_$$ANDROID_TARGET_ARCH \
-ltidy
ANDROID_EXTRA_LIBS += \
$$PREFIX/lib/$$TRIPLE/$$API/libcrypto_1_1.so \
$$PREFIX/lib/$$TRIPLE/$$API/libssl_1_1.so \
$$PREFIX/lib/$$TRIPLE/$$API/libcurl.so \
$$PREFIX/lib/$$TRIPLE/$$API/libtidy.so \
$$PREFIX/lib/$$TRIPLE/$$API/libicclient.so \
$$QT_ANDROID_LIBDIR/libqicclient_$${ANDROID_TARGET_ARCH}.so
assets.path = /assets
assets.files = $$CA_BUNDLE
INSTALLS += assets
}
|
